'Generate XMLAll: 

Option Public
Option Declare


Sub Initialize
	
	'Created May 3, 2008
	'
	'No warranty or other guaranty provided, Your mileage may vary, and "It worked for me!" all apply. :)
	'
	'Creates XML file to be used for creating Quickr Entry places for all entries in a directory
	'This can be run from an agent outside of the directory, or within it with a couple changes.
	'You'll also need to change the server name to match your Quickr server, or you could wait and just change the value in the XML file
	
	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim view As NotesView
	Dim viewnav As NotesViewNavigator
	Dim viewentry As NotesViewEntry
	Dim doc As NotesDocument
	Dim fileNum As Integer
	Dim filename As String
	Dim email As notesitem
	
	Set db = session.GetDatabase("" , "names.nsf")
	Set view = db.GetView("People")
	Set viewnav = view.CreateViewNav()
	Set viewentry = viewnav.GetFirstDocument()
	
	fileNum% = Freefile()
	fileName$ = "c:\temp\quickrentry.xml"
	
	Open fileName$ For Output As fileNum%
	Print #filenum%, "<?xml version=""1.0"" ?>"
	Print #fileNum%, "<!--Can be used to import users into Quickr Entry-->"
	Print #fileNum%, "<service>"
	Print #fileNum%, "<servers>"
	Print #fileNum%, "<server>"
	Print #fileNum%, "<hostname>server.domain.com</hostname>"	'Change the server name to the FQDN of the Quickr server
	Print #fileNum%, "<places>"
	
	While Not (viewentry Is Nothing) 
		Set doc = viewentry.Document
		If (doc.HasItem("InternetAddress") ) Then
			Set email = doc.GetFirstItem("InternetAddress")
			If ( email.text <> "") Then
				Print #fileNum%, "<place>"
				Print #fileNum%, "<email>" & doc.GetFirstItem("InternetAddress").text & "</email>"
				Print #fileNum%, "</place>"
			End If
		End If
		Set viewentry = viewnav.getnextdocument(viewentry)
	Wend
	
	Print #fileNum%, "</places>"
	Print #fileNum%, "</server>"
	Print #fileNum%, "</servers>"
	Print #fileNum%, "</service>"
	Close fileNum%
	
End Sub